Спарклайны

Спарклайн — маленький график прямо в ячейке: динамика продаж рядом со строкой товара, загрузка по месяцам рядом с фамилией сотрудника. Строится функцией SPARKLINE.

=SPARKLINE(B2:M2)

Синтаксис такой же, как в Google Таблицах: формулы переносятся оттуда без правки.

Опции

Второй аргумент — массив пар «ключ; значение»:

=SPARKLINE(B2:M2; {"charttype"; "column"; "color"; "#F2994A"})

Ключ	Значение	По умолчанию
charttype	line, column, bar или winloss	line
color	цвет графика: #rrggbb или английское имя (red, blue)	синий
negcolor	цвет отрицательных столбиков для column и winloss	красный
linewidth	толщина линии для line	1,25
ymin, ymax	границы оси значений	по данным

Незнакомые опции игнорируются: формула, скопированная из чужой таблицы, не сломается.

Типы графиков

line — ломаная по значениям. Пустые и текстовые ячейки диапазона считаются пропусками, линия на них разрывается.

column — столбики от нулевой линии. Отрицательные значения красятся цветом negcolor.

winloss — столбики одинаковой высоты: вверх для положительных значений, вниз для отрицательных. Полезно для серий «выиграл/проиграл», где важен знак, а не величина.

bar — горизонтальная полоса из сегментов: ширина каждого пропорциональна доле значения в сумме, вся полоса занимает ячейку целиком. С верхней границей полоса считается от неё, а не от суммы, — так получается индикатор прогресса: =SPARKLINE(A1; {"charttype"; "bar"; "ymax"; 100}) при значении 60 закрасит 60% ячейки. Отрицательные значения полоса не показывает.

Excel и Google Таблицы

Функции SPARKLINE в Excel нет: там спарклайн — не формула, а свойство листа со ссылкой на диапазон. Поэтому при выгрузке в .xlsx наша формула превращается в нативный спарклайн Excel, который он рисует сам, а при импорте такого файла обратно снова становится формулой. У Google Таблиц выгрузка в .xlsx спарклайн теряет — ячейка приходит пустой.

Excel требует ссылку на диапазон

Excel хранит не значения, а ссылку на исходный диапазон. Поэтому SPARKLINE(B2:M2) выгружается полноценно, а спарклайн по списку чисел прямо в формуле (SPARKLINE({1; 5; 3})) — нет: он уедет текстовой развёрткой блоками ▁▅█.

Из Google Таблиц формулы переносятся как есть. Разница только в разделителях: в Табуле аргументы и пары опций разделяются точкой с запятой, потому что запятая занята под десятичный разделитель.

Примеры

Динамика продаж по месяцам рядом с итогом:

=SPARKLINE(B2:M2)

Столбики с фирменным цветом и красными провалами:

=SPARKLINE(B2:M2; {"charttype"; "column"; "color"; "#F2994A"; "negcolor"; "#E6363E"})

Прибыльные и убыточные месяцы одним взглядом:

=SPARKLINE(B2:M2; {"charttype"; "winloss"})

Одинаковая шкала у нескольких строк — чтобы графики сравнивались между собой:

=SPARKLINE(B2:M2; {"ymin"; 0; "ymax"; 100})